从标准alv返回内表数据

【原创】从标准alv返回内表数据

栏目：ABAP 作者：在海边看星星阅读：（1612）更新于：2023-02-27 16:33

DATA: ls_data TYPE REF TO data.    
FIELD-SYMBOLS: <lt_data> TYPE ANY TABLE,
        <l_data>  TYPE any.
               
  rt_werks = VALUE #( BASE rt_werks (  sign = 'I'
                                       option = 'EQ'
                                       low = p_werks )
                     ).  
  
*取标准事务代码COMLWIPDISP中在产品价格差异
  cl_salv_bs_runtime_info=>set( EXPORTING display  = abap_false
                                          metadata = abap_false
                                          data     = abap_true ).

  SUBMIT display_wip_obj_ml WITH bukrs = p_bukrs
                            WITH werk IN rt_werks
                            WITH material IN s_matnr
                            WITH auftrag IN s_aufnr
                            WITH period = p_poper
                            WITH gjahr = p_gjahr
                            AND RETURN EXPORTING LIST TO MEMORY."TCODE:COMLWIPDISP

  TRY.
      cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = ls_data ).
      ASSIGN ls_data->* TO <lt_data>.
    CATCH cx_salv_bs_sc_runtime_info.

      MESSAGE `UNABLE TO RETRIEVE ALV DATA` TYPE 'E'.
  ENDTRY.

  cl_salv_bs_runtime_info=>clear_all( ).

  IF <lt_data> IS ASSIGNED.
    LOOP AT <lt_data> ASSIGNING <l_data>.

      MOVE-CORRESPONDING <l_data> TO gs_return_out.

      APPEND gs_return_out TO gt_return_out.

    ENDLOOP.
    SORT gt_return_out BY matnr aufnr.
    ENDIF.

相关方法

cl_salv_bs_runtime_info

SET（） - 此方法初始化类，它应该在程序调用ALV报告程序之前被调用。
参数：

1.DISPLAY - 将它设为abap_false，强制所有后续ALV报告在“黑暗模式”下运行，也就是说，ALV不会被输出到GUI。

2.METADATA - 将它设为abap_false，防止基本信息被取到内存中。

3.DATA - 将它设为abap_true，迫使数据表导出到内存而不是显示报表。

 

GET_DATA_REF（） - 非常灵活的GET_DATA*方法，这种方法可以用来访问该数据表变量的引用（动态而且易用），所以即使不知道ALV数据表的结构也没关系。
参数：

1.R_DATA - 输出ALV数据表。

2.R_DATA_LINE - 如果执行的ALV有HEADER的（可选）。

 

GET_DATA（） - 如果知道需要调用的ALV数据表的结构，可以使用这个方法。
参数：

1.T_DATA - 输出参数数据表。

2.T_DATA_LINE - 如果执行的ALV有HEADER（可选）。

 

CLEAR_ALL（） - 此方法清除在set（）方法设置的标志。如果之后本程序还需要显示其他ALV 那么这个方法非常重要。
转载自 (8条消息) ABAP cl_salv_bs_runtime_info 读取其他程序显示的ALV_cl_salv_bs_pdf未知_calla_wang的博客-CSDN博客

非特殊说明，本文版权归在海边看星星所有，转载请注明出处.

本文标题：从标准alv返回内表数据

本文网址：http://www.hysvr.com.com/article-43.html.

本文标签：ABAP

上一篇： FAGL_FCV 不触发增强...

下一篇：批量复制角色并修改权限参数文件组织级别数据...

我的评论